System Tray Icon Show/Hide List Full of Junk?

Whenever a program has the option to create an icon in your systray, it gets included in the Taskbar Settings -> Other System Tray Icons list. Sometimes, however, these options aren’t removed if you uninstall the program and sometimes duplicates can be made with apps that aren’t quite compatible. Annoying! Here’s how to clear that list up and keep it tidy.

Admittedly, this a pretty niche problem that won’t even come to most users attention, but it came to mine so I looked for a fix, and found a helpful one on https://www.winhelponline.com I have shamelessly scooped it up and reproduce it, without the thousand ads here for anyone that might come across it!

This fix will work on Windows 10 or 11 (and apparently even 8 and 9 but friends don’t let friend use out of date Operating Systems. Upgrade, you maniac!). 

All you need to do is create the following Visual Basic Script file. I promise, it’s easy. If you don’t have a code editor, just use notepad and name the file cleanup.vbs (or anything as long as it ends in .vbs) 

Paste the text below into the file, save it, and then run it from the command prompt! (that’s WIN+R and then cmd.exe) OR right click in the folder you made the file in and click “Open in Terminal”. When you’re in the folder that contains the file you made, just type “cscript ((yourfilename)).vbs” and bobs your uncle. You’ll have a clean Systray options window. 

'--------------------------------------------------------------------------------
'Clears items in the Customize Notifications (Taskbar Corner Overflow icons).
'This script can be used on Windows 11, 10, 8, 7, Vista, and XP.
'Written by Ramesh Srinivasan
'Created: Feb 13, 2007
'Revision: Aug 22, 2022
'Revision: May 05, 2023 'Clears the NotifyIconSettings registry key in addition.
'https://www.winhelponline.com/blog/
'--------------------------------------------------------------------------------

Option Explicit
Dim objWMIService, colItems, objItem, sCurrUsrName
Dim colProcList, objProcess, sNameOfUser, sUserDomain, sWel, sKey, sKey2
Dim colProperties

Dim WshShell: Set WshShell = CreateObject("WScript.Shell")
sKey = "HKCU\Software\Classes\Local Settings\Software\Microsoft\Windows\"
sKey = sKey & "CurrentVersion\TrayNotify\"
sKey2= "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\TrayNotify\"
Set objWMIService = GetObject ("winmgmts:\\" & "." & "\root\cimv2")

ExitExplorerShell
WScript.Sleep(3000)
ClearOverflowIcons
WScript.Sleep(2000)
StartExplorerShell

Sub ExitExplorerShell()
   'Get curr. user name
   Set colItems = objWMIService.ExecQuery("Select * From Win32_ComputerSystem")
   For Each objItem In colItems
      sCurrUsrName = objItem.UserName
   Next
   
   'Restart the Explorer shell
   Set colProcList = objWMIService.ExecQuery _
   ("Select * from Win32_Process Where Name = 'Explorer.exe'")
   For Each objProcess In colProcList
      colProperties = objProcess.GetOwner(sNameOfUser,sUserDomain)
      If UCase(sUserDomain & "\" & sNameOfUser) = UCase(sCurrUsrName) Then
         objProcess.Terminate(1)
      End If
   Next
End Sub

Sub ClearOverflowIcons
   'Clear the Customize Notifications dialog
   On Error Resume Next
   WshShell.Regdelete sKey & "IconStreams"
   WshShell.Regdelete sKey & "PastIconsStream"
   WshShell.Regdelete sKey2 & "IconStreams"
   WshShell.Regdelete sKey2 & "PastIconsStream"
   WshShell.Run "reg.exe delete " & """" & "HKCU\Control Panel\NotifyIconSettings" & _
   """" & " /f"
   On Error GoTo 0
End Sub

Sub StartExplorerShell
   WshShell.Run "explorer.exe"
End Sub

sWel = "For more tips and articles on Windows, visit us at:" & _
Chr(10) & Chr(10) & vbtab & "https://www.winhelponline.com/blog/"
Msgbox "Done!" & Chr(10) & Chr(10) & sWel & _
Chr(10), 64, "Taskbar Corner Overflow icons have been reset."